#!/usr/local/bin/perl
use warnings;
use strict;
my $in_table = 0;
my $tr;
my $td;
my @l = <>;
chomp @l;
s!(</?(?:table|td|tr))!\n$1!gi foreach @l;
@l = map { "$_\n" } map { split /\n/ } @l;

foreach my $i (0 .. $#l) {
    local $_ = $l[$i];
    local $SIG{__DIE__} = sub {
        chomp (my $msg = shift);
        die "$ARGV:$msg, line is: $l[$i]";
    };
    if (s/<table[^>]*//i) {
        die "nested tables not handled\n" if $in_table++;
    }
    # Buggy if <table> and </table> on same line, but who cares.
    if (s!</table[^>]*!!i) {
        die "mismatched </table>\n" if not $in_table;
        $in_table = 0;
    }
    if (s/<tr[^>]*>//i) {
        die "<tr> outside <table>\n" if not $in_table;
        die "<tr> inside another\n" if $tr;
        $tr = [];
        next unless /\S/;
    }
    if (s!</tr[^>]*>!!i) {
        die "mismatched </tr>\n" if not $tr;
        print join '|', '', @$tr, '';
        undef $tr;
    }
    if (s/<td[^>]*>//i) {
        die "<td> outside <tr>\n" if not $tr;
        die "<td> inside another\n" if defined $td;
        $td = '';
    }

    my $end_td = s!</td[^>]*>!!i;

    if (defined $td) {
        s!</?[pP][^>]*>!!g;
        s/&nbsp;/ /g;
        s/^\s+//; s/\s+$//;
        $td .= ' ' if length $td;
        $td .= $_;
    }
    else {
        print "$_\n";
    }

    if ($end_td) {
        die "mismatched </td>\n" if not defined $td;
        push @$tr, $td;
        undef $td;
    }
}
die "$ARGV:EOF inside <td>\n" if defined $td;
die "$ARGV:EOF inside <tr>\n" if $tr;
die "$ARGV:EOF inside <table>\n" if $in_table;